코딩각

오토핫키 HotString / HotKey - Autohotkey 가이드 2

IT일반
2022. 3. 27. 01:53

오토핫키를 처음 설치하면 어떤 스크립트를

작성해야 할지 감이 안올 수가 있습니다.

 

그럴때는 오토핫키의 핵심적인 기능인

HotKey와 HotString 스크립트를

작성하면서 요령을 익히는게 도움이 됩니다.

 

오토핫키 사용자의 대부분은 자주 사용하는

프로그램의 단축키나 웹사이트 연결 같이

기본적인 스크립트를 가장 빈번하게

사용하게 된다고 합니다. 이번 포스팅에는

실용적인 스크립트를 알아보겠습니다.

 

오토핫키와 에디터의 설치는 다음의

포스팅을 참고합니다.

 

Autohotkey 시작하기 / 설치 (SciTE 에디터) - Autohotkey 가이드 1

 

Autohotkey 시작하기 / 설치 (SciTE 에디터) - Autohotkey 가이드 1

Autohotkey(오토핫키) 오토핫키는 윈도우 시스템에서 자동키 매크로를 만들 수 있는 프로그램입니다. 매크로 뿐만 아니라 스크립트 프로그램을 만들 수 있는 프로그래밍 언어입니다. 윈도우 운영

digiconfactory.tistory.com

 

이메일 주소 핫스트링(HotString)

 

요즘은 이메일을 로그인 아이디로

많이 사용합니다. 로그인 정보를 브라우저에

저장하기도 하지만 보안상 저장하지 않는

사람들도 있습니다. 또 여러개의 이메일 주소를

사용하는 경우도 있는데요. 매번 이메일 주소를

기억해서 타이핑을 반복하는 것이

지겨울 수도 있습니다. 이럴 때 HotString을

한번 사용해 볼 때입니다.

 

핫스트링 문법은 다음과 같습니다.

::단축문자열::변경 문자열

 

다음은 nm을 타이핑하고 종료 문자열을

(Enter, Space, Tab, -, . 등) 입력하면

:: 뒤에 있는 kayken@naver.com으로 변경합니다.

::nm::kayken@naver.com

nm 은 naver main email 의 줄임말로

규칙을 정했습니다. 규칙은 본인이

잘 이해할 수 있도록 정합니다.

ns 는 naver sub email 이런 식으로

만들면 네이버에 2개의 메일이 있는데

하나는 main 하나는 sub 처럼 할 수 있습니다.

 

구글 메일같은 경우 gm - google main email

gs - google main email 과 같이 한다면

kyt8093tymoc@gmail.com같이 아무리 길고

복잡한 주소가 몇개라도 바로 불러올 수 있습니다.

 

HotString에는 유용한 옵션이 있는데

다음처럼 적용하는 방식으로 사용하면

타이핑 도중 원하지 않는 변환을

높은 확률로 방지할 수 있습니다.

 

*는 타이핑이 끝나면 종료문자(ending character)

없이도 바로 변환이 됩니다.

끝에 @나 .을 붙이면 nm@ nm. 이런 문자는

거의 사용되지 않기 때문에 타이핑 중에

의도치 않은 자동 변환할 확률이 낮습니다.

이 방법은 오토핫키 커뮤니티에서도

많이 추천하는 방식입니다.

:*:nm@::kayken@naver.com

:*:nm.::kayken@naver.com

비즈니스 카드 등

이메일이나 블로그, SNS 등 작성시 끝에

비즈니스 카드를 붙이기도 합니다.

여러줄의 문자열로 변환하는 방법은

몇개가 있는데 아래의 HotString처럼

`n 을 붙여서 여러줄을 사용합니다.

:*:card@::name: kay`nemail: kayken@naver.com`nblog: https://digiconfactory.tistory.com/

 

card@를 타이핑하면 바로 변경됩니다.

 

name: kay
email: kayken@naver.com
blog: https://digiconfactory.tistory.com/

 

( ) 괄호를 사용하면 코드 스니펫을

만들 수도 있습니다. 이때는 에디터에 따라

공백문자나 탭문자가 더 들어가는 경우도

있으니 테스트를 한 후 조절하도록 합니다.

::cstart::
(
#include<stdio.h>

int main()
{
    printf("Hello World!\n");
    return 0;
}
)

 

티스토리에 적용할 애드센스를

핫스트링으로 만들었습니다.

코드를 복사 붙여넣기 안해도 됩니다.

 

::adcd::
(
<center>
    <ins class="adsbygoogle"
         style="display:inline-block;width:336px;height:280px"
         data-ad-client="ca-pub-번호"
         data-ad-slot="슬롯번호"></ins>
    <script>
        (adsbygoogle = window.adsbygoogle || []).push({});
    </script>
</center>
)

시간 표시

함수를 사용하면 시간을 가져올 수 있습니다.

 

상세한 포맷은 오토핫키 문서 에서

확인할 수 있고 다음의 예제는

오늘 날짜와 현재 시간 사용법입니다.

 

; 오늘 날짜
:*:today@::
    FormatTime, CurrentDate, , yyyy년 M월 dd일
    SendInput %CurrentDate%
return

; 현재 시간
:*:wt@::
    FormatTime, CurrentTime, , H시 m분 s초
    SendInput %CurrentTime%
return


:*:ts@::
FormatTime, TimeString,, Time
MsgBox The current time is %TimeString%.
return

 

HotKey 설정

핫키설정은 심볼 문자를 알아야 됩니다.

 

^ 컨트롤키

# 윈도우키

! 알트키

+ 쉬프트키

& 키조합 생성자

 

^c 는 컨트롤 + c 를 의미하고

#z 는 윈도우키 + z

!k 는 알트키 + k

+!p 는 쉬프트 + 알트 + p

1 & 2 는 1과 2를 동시에 누름을 의미함

 

다음은 사용예입니다.

컨트롤 + n 으로 메모장을 실행합니다.

;노트패트 실행
^n::
run, notepad
return

구글 검색창을 실행합니다.

#z::
run, https://www.google.com/
return

 

오토핫키의 프로그램의 실행과 종료를

컨트롤하는 함수도 있습니다.

 

리로드와 에디트는 편집하면서

HotKey를 테스트할 때 편리합니다.

앱종료는 현재 실행중인 HotKey를 종료합니다. 

; 리로드와 에디트 (Reload and Edit)
^r::
Reload
return

^e::
Edit
return

; 앱 종료하기 (Exit)

^q::
ExitApp
return

구글과 유튜브 바로 검색하기

하이라이트한 텍스트를 구글에 바로 검색합니다.

(혹은 클립보드의 텍스트) 컨트롤+시프트+F

^+F::
Send, ^c
Sleep 100
Run, https://www.google.com/search?q=%clipboard%
Return

하이라이트한 텍스트를 바로 유튜브 검색합니다.

(혹은 클립보드의 텍스트) 컨트롤+시프트+Y

^+Y::
Send, ^c
Sleep 100
Run, https://www.youtube.com/results?search_query=%clipboard%
return

Sleep 100은 웹브라우저가 실행되고

페이지가 로드된 후에 메시지를

전달하기 위해서 입니다. 바로 스크립트가

실행되면 문자열을 놓칠 수 있습니다.

느린 컴퓨터에서는 Sleep 수치를

조절해야할 수 있습니다. 1000이 1초 기준.

 

웹브라우저 쿼리기능은

검색을 자주하는 사람이라면

컴퓨팅의 질이 달라집니다

 

URL 쿼리하는 사이트들은

비슷한 형태로 만들 수 있습니다.

 

포탈의 검색쿼리를 찾아보면

네이버는 다음과 같이 나옵니다.

https://search.naver.com/search.naver?query= 

여기에 %clipboard% 변수를

넣어서 위의 예제처럼 바꾸면 됩니다.

^+N::
Send, ^c
Sleep 100
Run, https://search.naver.com/search.naver?query=%clipboard%
return

 

네이버 쿼리같은 경우 뉴스, 동영상,

쇼핑 등 쿼리가 여러개이니 자주 보는

페이지에 맞게 바꿀 수 있습니다.

 

URL에 대한 기초지식만 있어도

여러가지 응용을 할 수 있을 겁니다.

 

그 밖에 팁

하나의 스크립트를 여러개 실행하는 것을

방지하기 위해서 스크립트에 다음의

지시자 SingleInstance 를 넣어줍니다.

 

#SingleInstance, Force ;인스턴스 1개만 론칭

 

*이 정도 기능만 사용하더라도 작업 자동화에

상당히 도움이 될 것입니다. 다음 포스팅에서는

오토핫키의 고급 기능들을 알아보겠습니다.

저작자표시 비영리 변경금지

공유하기

facebook twitter kakaoTalk kakaostory naver band
'IT일반' 의 관련글

티스토리툴바